resource "vcd_org_vdc" "vdc_services" {
  name        = var.vmwareVdc
  description = "vcd description"
  org         = var.vmwareOrg

  allocation_model               = "Flex"
  elasticity                     = true
  include_vm_memory_overhead     = false
  network_pool_name              = var.providerNetworkPoolName
  provider_vdc_name              = var.providerVdcName
  network_quota                  = 1
  cpu_guaranteed                 = var.cpuGuaranteed
  cpu_speed                      = var.vmwareCpuspeed
  memory_guaranteed              = var.memGuaranteed

  compute_capacity {
    cpu {
      allocated                  = var.cpuAllocated
      limit                      = var.cpuAllocated
    }

    # limit ставится в unlimited, чтобы можно было создать ВМки по размеру аллоцирования (впритык), уместив overhead по памяти
    # Клиент выйти за allocated не сможет, но и дополнительно забираться память для гипервизора не будет
    memory {
      allocated                  = var.memAllocated
      limit                      = 0
    }
  }

  metadata_entry {
    key         = "instanceUid"
    type        = "MetadataStringValue"
    value       = var.instanceUid
    user_access = "PRIVATE"
    is_system   = true # Requires System admin privileges
  }

  dynamic "metadata_entry" {
    for_each = var.enabled ? [] : [1]
    content {
      key         = "dtStopped"
      type        = "MetadataStringValue"
      value       = var.dtStopped
      user_access = "PRIVATE"
      is_system   = true # Requires System admin privileges
    }
  }

  dynamic "storage_profile" {
    for_each = local.storage_config_with_default
    content {
      name    = storage_profile.value.name
      limit   = storage_profile.value.size
      enabled = true
      default = storage_profile.value.default
    }
  }

  default_compute_policy_id      = var.defaultComputePolicyId
  vm_sizing_policy_ids           = local.all_sizing_policies

  enabled                        = var.enabled
  enable_thin_provisioning       = true
  enable_fast_provisioning       = false # Если включить параметр, то диски менять системные не получится
  delete_force                   = true
  delete_recursive               = true
}