146 lines
8.3 KiB
Plaintext
146 lines
8.3 KiB
Plaintext
<cfcomponent extends="taffy.core.resource" taffy:uri="/instanceOperations/{instanceOperationUid}">
|
|
|
|
<cfsilent>
|
|
<cfimport prefix="m" taglib="../lib"/>
|
|
<cfset this.helper=CreateObject("component","lib.rest_api_helper")/><!---*** странно, почему мы его видим?---><!---вынести в апп?--->
|
|
</cfsilent>
|
|
|
|
|
|
<cffunction name="get" hint="Операция над экземпляром сервиса"><!--- *** TODO проверка принадлежности тенанту --->
|
|
<cfargument name="instanceOperationUid" type="string" required=true hint="type:guid"/>
|
|
<cftry>
|
|
<cfset this.helper.validateField(arguments, "instanceOperationUid", "guid")/>
|
|
<cfcatch type="invalidParamValue">
|
|
<cfreturn representationOf(this.helper.formatBadRequestError(cfcatch)).withStatus(400)/>
|
|
</cfcatch>
|
|
</cftry>
|
|
|
|
<cfset var out={}/>
|
|
|
|
<cfquery name="local.qInstanceOperation" result="local.result">
|
|
select
|
|
<m:field_set titleMapOut="local.titleMap" lengthOut="local.fieldCount">
|
|
<m:field title="instance Operation Uid">o.instance_operation_uid::text as instance_operation_uid</m:field>
|
|
<m:field title="operation">o.operation</m:field>
|
|
<m:field title="instance_uid">o.instance_uid::text as instance_uid</m:field>
|
|
<m:field title="Отправка">to_char(o.dt_submit, 'YYYY-MM-DD"T"HH24:MI:SS.FF3TZHTZM') as dt_submit</m:field>
|
|
<m:field title="Рез.">o.submit_result</m:field>
|
|
<m:field>o.error_log</m:field>
|
|
<m:field title="Начало">to_char(o.dt_start, 'YYYY-MM-DD"T"HH24:MI:SS.FF3TZHTZM') as dt_start</m:field>
|
|
<m:field title="Завершение">to_char(o.dt_finish, 'YYYY-MM-DD"T"HH24:MI:SS.FF3TZHTZM') as dt_finish</m:field>
|
|
<m:field title="Длит. сек">extract('epoch' from coalesce(o.dt_finish,CURRENT_TIMESTAMP)- o.dt_start) as duration</m:field>
|
|
<m:field title="Успешно">o.is_successful</m:field>
|
|
<m:field title="Экземпляр">e.display_name</m:field>
|
|
<m:field title="service_id">e.service_id</m:field>
|
|
<m:field title="specification_item_id">e.specification_item_id</m:field>
|
|
<m:field title="dt_created">to_char(o.dt_created, 'YYYY-MM-DD"T"HH24:MI:SS.FF3TZHTZM') as dt_created</m:field>
|
|
<m:field title="Услуга">v.svc</m:field>
|
|
<m:field>so.svc_operation_id</m:field>
|
|
</m:field_set>
|
|
from instance_operation o
|
|
join instance e on (o.instance_uid=e.instance_uid)
|
|
join specification_item i on (e.specification_item_id=i.specification_item_id)
|
|
join specification s on (i.specification_id=s.specification_id)
|
|
join contract d on (s.contract_id=d.contract_id)
|
|
join contragent k on (d.contragent_id=k.contragent_id)
|
|
join svc v on (e.service_id=v.svc_id)
|
|
join svc_operation so on (v.svc_id=so.svc_id AND o.operation=so.operation)
|
|
where <!--- u.usr_id=<cfqueryparam cfsqltype="cf_sql_integer" value=#arguments.usrId#/> AND--->
|
|
o.instance_operation_uid=<cfqueryparam cfsqltype="cf_sql_other" value="#arguments.instanceOperationUid#" null=#!isValid('guid',arguments.instanceOperationUid)#/>
|
|
AND s.specification_id=<cfqueryparam cfsqltype="cf_sql_integer" value=#arguments.specificationId#/>
|
|
</cfquery>
|
|
|
|
<cfif local.qInstanceOperation.recordCount EQ 0>
|
|
<cfreturn representationOf(this.helper.formatMessage("Not Found")).withStatus(404)/>
|
|
</cfif>
|
|
|
|
<!--- Чтобы не нагружать второй селект проверкой принадлежности клиенту, мы берем ключ не из аргументов, а из первого запроса --->
|
|
<cfquery name="local.qStage" result="local.result">
|
|
select
|
|
<m:field_set titleMapOut="local.stageMap" lengthOut="local.fieldCount">
|
|
<m:field>ios.instance_operation_stage_uid::text as instance_operation_stage_uid</m:field>
|
|
<m:field>ios.stage</m:field>
|
|
<m:field>ios.is_successful</m:field>
|
|
<m:field>to_char(ios.dt_start, 'YYYY-MM-DD"T"HH24:MI:SS.FF3TZHTZM') as dt_start</m:field>
|
|
<m:field>to_char(ios.dt_finish, 'YYYY-MM-DD"T"HH24:MI:SS.FF3TZHTZM') as dt_finish</m:field>
|
|
<m:field>round(extract('epoch' from coalesce(ios.dt_finish,CURRENT_TIMESTAMP)- ios.dt_start),1) as duration</m:field>
|
|
<!--- <m:field formatter=#function(x){return (deserializeJson(x))}#>ios.stage_data::text as stage_data</m:field> --->
|
|
</m:field_set>
|
|
from instance_operation_stage ios
|
|
where ios.instance_operation_uid=<cfqueryparam cfsqltype="cf_sql_other" value="#local.qInstanceOperation.instance_operation_uid#" null=#!isValid('guid',local.qInstanceOperation.instance_operation_uid)#/>
|
|
order by dt_start asc
|
|
</cfquery>
|
|
|
|
<cfquery name="local.qState" result="local.result">
|
|
select
|
|
<m:field_set titleMapOut="local.stateTitleMap" lengthOut="local.fieldCount">
|
|
<m:field title="instance_state_uid">st.instance_state_uid::text as instance_state_uid</m:field>
|
|
<m:field title="v.">st.version</m:field>
|
|
<m:field title="creator_id">st.creator_id</m:field>
|
|
<m:field title="dt_state">to_char(st.dt_state, 'YYYY-MM-DD"T"HH24:MI:SS.FF3TZHTZM') as dt_state</m:field>
|
|
<m:field title="is_test">st.is_test</m:field>
|
|
<m:field title="instance_operation_uid">st.instance_operation_uid::text as instance_operation_uid</m:field>
|
|
<m:field title="instance_data" formatter=#function(x){return (deserializeJson(x))}#>st.instance_data::text as instance_data</m:field>
|
|
</m:field_set>
|
|
from instance_state st
|
|
where st.instance_operation_uid=<cfqueryparam cfsqltype="cf_sql_other" value="#local.qInstanceOperation.instance_operation_uid#" null=#!isValid('guid',local.qInstanceOperation.instance_operation_uid)#/>
|
|
order by st.version desc limit 1
|
|
</cfquery>
|
|
|
|
<cfquery name="local.qCfsParam" result="local.result">
|
|
select
|
|
<m:field_set titleMapOut="local.cfsParamTitleMap" lengthOut="fieldCount">
|
|
<m:field title="instance_operation_cfs_param_uid">iop.instance_operation_cfs_param_uid::text as instance_operation_cfs_param_uid</m:field>
|
|
<!--- <m:field title="instance_operation_uid">instance_operation_uid::text as instance_operation_uid</m:field> --->
|
|
<m:field>sop.svc_operation_cfs_param_id</m:field>
|
|
<m:field>iop.param_value</m:field>
|
|
<m:field>to_char(iop.dt_created, 'YYYY-MM-DD"T"HH24:MI:SS.FF3TZHTZM') as dt_created</m:field>
|
|
<m:field>iop.creator_id</m:field>
|
|
<m:field>sop.svc_operation_cfs_param</m:field>
|
|
<m:field>sop.label</m:field>
|
|
<m:field>sop.data_type</m:field>
|
|
<m:field formatter=#function(x){return listToArray(x);}#>sop.value_list</m:field>
|
|
<m:field>sop.ref_svc_id</m:field>
|
|
<m:field>sop.is_required</m:field>
|
|
<m:field>sop.default_value</m:field>
|
|
<m:field>sop.regex</m:field>
|
|
<m:field>sop.unique_scope</m:field>
|
|
<m:field>sop.descr</m:field>
|
|
<m:field>iop.note</m:field>
|
|
</m:field_set>
|
|
from svc_operation_cfs_param sop
|
|
left outer join instance_operation_cfs_param iop
|
|
on (sop.svc_operation_cfs_param_id=iop.svc_operation_cfs_param_id
|
|
AND iop.instance_operation_uid = <cfqueryparam cfsqltype="cf_sql_other"
|
|
value="#local.qInstanceOperation.instance_operation_uid#"
|
|
null=#!isValid('guid',local.qInstanceOperation.instance_operation_uid)#/>
|
|
)
|
|
where sop.svc_operation_id = <cfqueryparam cfsqltype="cf_sql_integer"
|
|
value=#local.qInstanceOperation.svc_operation_id#
|
|
null=#!isValid('integer',local.qInstanceOperation.svc_operation_id)#/>
|
|
order by sop.svc_operation_cfs_param_id
|
|
</cfquery>
|
|
|
|
<cfset "out.queryDurationMs"=getTickCount() - request.startTickCount/>
|
|
|
|
<cfset "out.instance" = this.helper.appendRecord(
|
|
structNew("linked"), "", local.titleMap, local.qInstanceOperation, this.helper.snake2camel
|
|
)/>
|
|
|
|
<cfset "out.instance.cfsParams"=[]/>
|
|
<cfloop query=#local.qCfsParam#>
|
|
<cfset arrayAppend(out.instance.cfsParams, this.helper.appendRecord(structNew("linked"), "", local.cfsParamTitleMap, local.qCfsParam, this.helper.snake2camel))/>
|
|
</cfloop>
|
|
|
|
<cfset "out.instance.stages"=[]/>
|
|
<cfloop query=#local.qStage#>
|
|
<cfset arrayAppend(out.instance.stages, this.helper.appendRecord(structNew("linked"), "", local.stageMap, local.qStage, this.helper.snake2camel))/>
|
|
</cfloop>
|
|
|
|
<cfset "out.instance.state"=(local.qState.recordCount GT 0) ? this.helper.appendRecord(structNew("linked"), "", local.stateTitleMap, local.qState, this.helper.snake2camel) : {}/>
|
|
|
|
<cfset "out.runDurationMs"=getTickCount() - request.startTickCount/>
|
|
<cfreturn representationOf(out) />
|
|
</cffunction>
|
|
|
|
</cfcomponent> |