upload.cfm: приём файлов

2026-06-18 14:16:39 +04:00
parent 3975954f5d
commit 2e216a9a3f
1 changed files with 67 additions and 0 deletions
@@ -0,0 +1,67 @@
 <cfsetting showdebugoutput="no" enablecfoutputonly="true">
 <cfheader name="Content-Type" value="application/json; charset=utf-8">
 <cfset result = {ok: false, error: "no file"}>
 <cftry>
    <cfif structKeyExists(form, "files") AND len(form.files)>
        <cffile action="upload" fileField="files" destination="#getTempDirectory()#" nameConflict="makeUnique" result="upload">
        <cfset mime = "application/octet-stream">
        <cfif listLast(upload.clientFile, ".") EQ "pdf">
            <cfset mime = "application/pdf">
        <cfelseif listLast(upload.clientFile, ".") EQ "docx">
            <cfset mime = "application/vnd.openxmlformats-officedocument.wordprocessingml.document">
        <cfelseif listLast(upload.clientFile, ".") EQ "doc">
            <cfset mime = "application/msword">
        <cfelseif listLast(upload.clientFile, ".") EQ "zip">
            <cfset mime = "application/zip">
        </cfif>
        <cffile action="readBinary" file="#upload.serverDirectory#/#upload.serverFile#" variable="fileBytes">
        <cfquery datasource="baza">
            INSERT INTO documents (filename, mime_type, original_bytes, status) 
            VALUES (
                <cfqueryparam value="#upload.clientFile#" cfsqltype="cf_sql_varchar">,
                <cfqueryparam value="#mime#" cfsqltype="cf_sql_varchar">,
                <cfqueryparam value="#fileBytes#" cfsqltype="cf_sql_blob">,
                'uploaded'
            )
        </cfquery>
        <cfquery name="doc" datasource="baza">
            SELECT id FROM documents 
            WHERE filename = <cfqueryparam value="#upload.clientFile#" cfsqltype="cf_sql_varchar">
            AND status = 'uploaded' 
            ORDER BY created_at DESC LIMIT 1
        </cfquery>
        <cfquery datasource="baza">
            INSERT INTO contracts (number, client) VALUES (
                <cfqueryparam value="б/н #dateFormat(now(), 'yyyymmdd')#-#timeFormat(now(), 'HHmm')#" cfsqltype="cf_sql_varchar">,
                ''
            )
        </cfquery>
        <cfquery name="cid" datasource="baza">
            SELECT id FROM contracts ORDER BY created_at DESC LIMIT 1
        </cfquery>
        <cfquery datasource="baza">
            INSERT INTO supplements (contract_id, document_id, type) VALUES (
                <cfqueryparam value="#cid.id#" cfsqltype="cf_sql_varchar">,
                <cfqueryparam value="#doc.id#" cfsqltype="cf_sql_varchar">,
                'initial'
            )
        </cfquery>
        <cfset result = {ok: true, contract_id: cid.id, doc_id: doc.id, filename: upload.clientFile, size: upload.fileSize}>
    </cfif>
    <cfcatch>
        <cfset result = {ok: false, error: cfcatch.message, detail: cfcatch.detail}>
    </cfcatch>
 </cftry>
 <cfoutput>#serializeJSON(result)#</cfoutput>